source: community/nibbler/api_snmp.pl @ 197

#!/usr/bin/perl

use JSON;
use LWP::UserAgent;
use strict;
use warnings;

my ($url, $user, $pass, $debug, $template_basename, $api_version, 
        $hostname_only, $snmpgroup, $templategroup);
my (%stats, %prog_api_version);

#$url = "http://localhost/zabbix-1.8.1";
#$url = "http://localhost/zabbix-1.8.2";
#$url = "http://localhost/zabbix-10922";  
#$url = "http://localhost/zabbix-10994";
$url=$ARGV[0];

$user = "admin";
$pass = "zabbix";
$snmpgroup = "SNMP Devices";    
$templategroup = "Templates";   # must exist    
$hostname_only=1;
$debug = 2; # 0 none, 1 some debug prints, 2 includes json strings (multiline)
$template_basename = "Template_auto_";

# supported API versions 
$prog_api_version{"1.1"}=1; # zabbix 1.8.1
$prog_api_version{"1.2"}=1; # zabbix 1.8.2

sub snmp { # adds nonexistant items for host arg1 to template-id arg2
        my ($switch, $template_name) = @_;
        my ($formula, $delay, $history, $trends, $priority, $community);
        my (%oid, %delta, %description, %triggerDsc, %triggerXp);

        $delay=180;
        $history=365;
        $trends=730;
        $formula=1;
        $priority=4;
        $community="public";

        $delta{'ifOperStatus'}="1";
        $description{'ifOperStatus'}="Interface oper status on ";

        $delta{'ifSpeed'}="1";
        $description{'ifSpeed'}="Interface speed on ";

        $oid{'snVLanByPortStpTopChanges'}="1.3.6.1.4.1.1991.1.1.3.2.1.1.20";
        $delta{'snVLanByPortStpTopChanges'}="2";
        $description{'snVLanByPortStpTopChanges'}="STP Topology Change on VLAN #";

        $delta{'ifInErrors'}="1";
        $description{'ifInErrors'}="Interface input errors on ";

        $delta{'ifOutErrors'}="1";
        $description{'ifOutErrors'}="Interface output errors on ";

        $delta{'ifInOctets'}="1";
        $description{'ifInOctets'}="Interface in octets on ";

        $delta{'ifOutOctets'}="1";
        $description{'ifOutOctets'}="Interface outoctets on ";

        $oid{'ifCollision'}="1.3.6.1.2.1.16.1.1.1.13";
        $delta{'ifCollision'}="2";
        $description{'ifCollision'}="Interface collisions on ";

        $triggerDsc{'ifOperStatus'}="ifOperStatus on {HOSTNAME} changed on if SUBME";
        $triggerXp{'ifOperStatus'}="{{HOSTNAME}:ifOperStatus.SUBME.diff(0)}=1";

        $triggerDsc{'ifSpeed'}="ifSpeed on {HOSTNAME} changed on if SUBME";
        $triggerXp{'ifSpeed'}="{{HOSTNAME}:ifSpeed.SUBME.diff(0)}=1";

        $triggerDsc{'ifInErrors'}="ifInErrors on {HOSTNAME} too high on if SUBME";
        $triggerXp{'ifInErrors'}="{{HOSTNAME}:ifInErrors.SUBME.diff(0)}=1";

        $triggerDsc{'ifOutErrors'}="ifOutErrors on {HOSTNAME} too high on if SUBME";
        $triggerXp{'ifOutErrors'}="{{HOSTNAME}:ifOutErrors.SUBME.diff(0)}=1";

        $triggerDsc{'snVLanByPortStpTopChanges'}="STP Topology Change occured on {HOSTNAME} on VLAN #SUBME";
        $triggerXp{'snVLanByPortStpTopChanges'}="{{HOSTNAME}:snVLanByPortStpTopChanges.SUBME.last(0)}>0";

        $triggerDsc{'ifCollision'}="Too many collisions occured on {HOSTNAME} on if SUBME";
        $triggerXp{'ifCollision'}="{{HOSTNAME}:ifCollision.SUBME.last(0)}>10";

# END OF USERCONFIG - DON'T TOUCH BELOW HERE!

        # get configured item keys and trigger expressions, hash, optionally skip .oO
        # or maybe just accept an json error on creation ....
        $stats{Hosts}++;
        my $template_id = gettemplateid($template_name);
        my %keys;
        my $items = apicall('Item.get', {hostids => $template_id, output => 'extend'});
        for my $i (0..$#$items){
                $keys{$items->[$i]->{key_}} = 1;
        }
        $stats{'Items preexisting'} += keys %keys;
        print "   read ".(keys %keys)." items from database\n" if $debug;       
        my ($key, $tree);
        foreach $key (keys %description){
                $tree=$key;
                if($oid{$tree}) { $tree = $oid{$tree}; }
                foreach(`/usr/bin/snmpwalk -v1 -cpublic -On $switch $tree`){
                        /\.(.*\.)(\d+)/;
                        my $oid=$1;
                        my $if=$2;
                        if ($keys{$key.".".$if}) {
                                $stats{'Items skipped'}++;
                                print "      skipping preexisting item ($stats{'Items skipped'})\n" if $debug;
                                next;
                        }
                        print "      create item desc: $description{$key}port $if delta: $delta{$key} oid: $oid$if\n" if $debug;
                        apicall('Item.create', {description => $description{$key}."port ".$if,  
                                                key_ => $key.".".$if, 
                                                hostid => $template_id, 
                                                delay => $delay,
                                                history => $history,
                                                trends => $trends,
                                                status => 0,            # default, active
                                                type => 1,              # SNMPv1
                                                snmp_community => $community,
                                                snmp_oid => $oid.$if,
                                                value_type => 3,        # numeric unsigend
                                                data_type => 0,         # decimal, default
                                                snmp_port => 161,
                                                delta => 1              # 0=simple 1=delta/second 2=delta
                                });                     
                        $stats{'Items created'}++;
                        if( !$triggerXp{$key} ){ next; }
                        my $desc=$triggerDsc{$key};
                        my $xp=$triggerXp{$key};
                        $desc =~ s/SUBME/$if/g;
                        $xp =~ s/SUBME/$if/g;
                        $xp =~ s/\{HOSTNAME\}/$template_name/g;
                        print "      create trigger descc: $desc xpression: $xp\n" if $debug;
                        apicall('Trigger.create', { description => $desc,
                                                        expression => $xp,
                                                        type => 0,
                                                        priority => $priority,
                                                        status => 0,    # 0=enabled, default=disabled
                                                        comments => '',
                                                        url => '',
                                                        templateid => 0 # mapped to template via item 
                                });
                        $stats{'Triggers created'}++;
                }
        }
}

sub apicall {
        my ($method , $params) = @_;
        print "$method:\n" if $debug;
        our ($mreq, $mres, $mua, $auth); 
        if (!$mreq){
                print "   setting up LWP... \n" if $debug;
                $mua = LWP::UserAgent->new;
                $mua->agent("swZBXAPI/0.1 ");
                $mreq = HTTP::Request->new(POST => "$url/api_jsonrpc.php");
                $mreq->content_type('application/json-rpc');
        }
        my $obj = {jsonrpc => '2.0',
                        method => $method,
                        params => $params,
                        auth => $auth,
                        id => $stats{'API calls'}++
                  };
        if (defined &to_json){          # there is different JSON.pm around....
                $obj = to_json($obj);
        } else {
                $obj = objToJson($obj);
        }
        $mreq->content($obj);
        print "    >".$mreq->content ."\n" if $debug > 1;
        $mres = $mua->request($mreq);
        if (!$mres->is_success) {print $mres->status_line, "\n";}
        print "    <".$mres->content ."\n" if $debug > 1;
        if (defined &from_json){        # there is different JSON.pm around....
                $mres = from_json($mres->content);
        } else {
                $mres = jsonToObj($mres->content);
        }
        if($mres->{result}) {
                print "   ".$mres->{result}."\n" if $debug;
        } else {
                die $mres->{error}->{message}." ".$mres->{error}->{data}." in $method\n";
        }
        if($method eq "user.authenticate") { $auth = $mres->{result} ;}
        return $mres->{result} ;
}

sub gettemplateid { # returns id of the template, creates it if necessary
        my ($template_name) = @_;
        my $groupid_template = apicall('HostGroup.getObjects', { name => $templategroup})->[0]->{groupid};
        my $template = apicall('Template.getObjects', { template => $template_name}) if ($api_version eq "1.1");
        my $template = apicall('Template.getObjects', { host => $template_name}) if ($api_version eq "1.2"); 
        my $templateid = 0;
        if ($template =~ /HASH/){ # zabbix bug workaround (ZBX-2205)
                for (keys %$template) { 
                        $templateid = $template->{$_}->{templateid};
                }
        } else {   # should never be called, array is only returned if no template is found....
                $templateid = $template->[0]->{templateid};
        }
        if (!$templateid) {  # create hostspecific template
                $stats{'Templates created'}++;
                my $res = apicall('Template.create', { host => $template_name,
                                                groups => $groupid_template
                                });
                for (keys %$res) { # should be one and one only
                        $templateid = $_ if ($api_version eq "1.1");
                        $templateid = $res->{templateids}->[0] if ($api_version eq "1.2");  
                }
        }
        return $templateid;
}


apicall('user.authenticate',{password => $pass, user => $user}); 
$api_version = apicall('APIInfo.version', { foo => 1}); 
if (!$prog_api_version{$api_version}) { die "unsupported API version: $api_version\n"; }
my $groupid = apicall('HostGroup.getObjects', { name => $snmpgroup})->[0]->{groupid};
my $hostarray = apicall('Host.get', {groupids => $groupid, extendoutput => 1});
for my $i (0..$#$hostarray){
        print $hostarray->[$i]->{hostid}.",".$hostarray->[$i]->{dns}.",".$hostarray->[$i]->{ip}."\n" if $debug;
        my $hostname = $hostarray->[$i]->{host};
        if ( $hostname =~ /[a-zA-Z]/ && $hostname_only ) { $hostname =~ s/\..*//g;}
        my $template_name = $template_basename.$hostname;
        my $templateid = gettemplateid($template_name);
        apicall('Template.linkTemplates', {templates => { templateid => $templateid }, hosts => { hostid => $hostarray->[$i]->{hostid}}}) if ($api_version eq "1.1");
        apicall('Template.massAdd', {templates => $templateid, hosts => $hostarray->[$i]->{hostid}}) if ($api_version eq "1.2"); 
        snmp ($hostarray->[$i]->{ip}, $template_name);
}

print "\n+---------------------+-------+\n";
foreach (keys %stats){
        printf "| %-20s|%6d |\n",$_,$stats{$_};
}
print "+---------------------+-------+\n";